maxreflect 8 // don't stagger reflection rendering at all
pvs 0; oqfrags 0 // to stress raw horsepower more, rather than bottleneck of query latency or PVS efficiency
glare 1; shadowmap 1; depthfx 1 // ensure always on
glarescale 2;blurglare 7 // use largest blur possible on glare
caustics 1; waterfallrefract 1; waterreflect 1; waterrefract 1; waterfade 1 // make sure always on, regardless of card's capabilities
zpass 1 // always enable, regardless of whether OQ is supported
filltjoints 1 // to be fairer on nvidia cards
maxtexsize 4096 // to be fairer on hardware that would normally be limited to 256x256 textures
maxdynlights 5 // to generate longer shaders than default
gpuskel 1; matskel 0 // use more expensive dual quaternion skeletal animation
reflectscissor 0 // make sure it always renders full reflections
rtscissor 0 // make sure glare always renders a full texture, doesn't effect depthfx/shadowmap much since they use blur tiles
maxfps 500 // default FPS cap of 200 is too low

sleep 1000 [demo "hades"]

demofpsmin = 1000
demofpsmax = 0
demofpssum = 0
demofpssamples = 0

printfps = [
    // echo raw FPS numbers 4 times a second
    curfps = (getfps 1)
    demofpssum = (+ $demofpssum $curfps)
    demofpssamples = (+ $demofpssamples 1)
    demofpsmin = (min $demofpsmin $curfps)
    demofpsmax = (max $demofpsmax $curfps)
    echo "FPS:" $curfps
    sleep 250 [printfps]
]

demorun = 0

demostart = [ 
    sleep 500 [follow "shmutz"]
    if (> $demorun 0) [
        sleep 1000 [
            echo "BENCHMARK STARTING"
            printfps
        ]
    ]
]

demoend = [
    clearsleep
    demorun = (+ $demorun 1)
    if (< $demorun 2) [
        sleep 1000 [demo "hades"]
    ] [
        demoscore = (div $demofpssum $demofpssamples)
        echo "BENCHMARK DONE:" $demoscore "AVG," $demofpsmin "MIN," $demofpsmax "MAX"
        quit
    ]
]